// Simon Ayrinhac, IMPMC, Sorbonne Université , (2024)
// 
// Résolution du déterminant de Sholte
// dans le cas d'une interface liquide / solide isotrope
///
// D'après l'article de :
//     Han, Q., Qian, M., & Wang, H.  Investigation of liquid∕ solid interface waves with laser excitation and photoelastic effect detection. Journal of applied physics, 100(9), (2006), Eq. (1)
// 

// (Exemple en fin de fichier)


function [vRe,VIm]=Func_Scholte_determinant(VL,VT,rhoS,VF,rhoF)
    
    // Paramètres IN
    // VL, VT, rhoS : paramètres du solide (vitesses longi., transverse, et masse volumiques)
    // VF, rhoF : paramètres du fluide (vitesse et masse volumiques)
    
    // Paramètres OUT
    // vRe, vIm :

visualisation=1;


    VR0=[1000:10:VF-1 VF+1:10:5000]; // evite la division par zéro 
    VI0=-100:10:500;

    [VR,VI] = meshgrid(VR0,VI0);
    V=VR+%i.*VI;
    
    

        
    VL2=VL.^2;
    VT2=VT.^2;
    A=(V./VT).^2;
    A4=(V./VT).^4;
    B=(V./VL).^2;
    C=(V./VF).^2;
    drho=rhoF/rhoS;
 

    
    y0=(2-A).^2-4.*((1-B).*(1-A)).^(1/2); 
    K=-%i.*drho.*A4.*((1-B).^(1/2)).*((C-1).^(-1/2));
    y1=y0+K; // Eq.(3.30) p.44 poly ondes Tony
    
    yf=abs(y1);//yf=log(abs(y1));
//    yf(find(yf>6))=6;

if visualisation==1
    
    /// Diagramme 3D --------------------------
    figure(1)
        surf(VR,VI,yf);
        f=gcf();
        f.color_map = jetcolormap(100);
        xtitle('Déterminant de Scholte','Real (m/s)','Imag (m/s)','')
        
    figure(2)
       grayplot(VR0,VI0,yf');
       xtitle('Déterminant de Scholte','Velocity, real part (m/s)','Velocity, imag part (m/s)');
       f=gcf();
       f.color_map = jetcolormap(64);
       colorbar(0,max(yf));
       f.background=-2; // fonds blanc   
end
       
    [val,pos]=min(yf);
 

  vRe=VR0(pos(2));
  VIm=VI0(pos(1));

endfunction

// Exemple -----------------------------------------------------------------
// D'après Glorieux et al (2001), interface : verre / eau 
// [vRe,vIm]=Func_Scholte_determinant(5712,3356,2500,1500,1000);
//
// disp(vRe)
// disp(vIm)
// Résultats : 3091. 110.