function [F,X,Xc]=Func_TF_fenetre(t,y,type_fenetre)

// S.Ayrinhac (2012)
// Transformée de Fourier discrète utilisant la TF rapide (FFT)
// Xc : coefficients de Fourier complexes

// Tests
if size(t,2)==1 // on ne veut que des vecteurs lignes
   t=t';
end
if size(y,2)==1 // on ne veut que des vecteurs lignes
   y=y';
end

if length(t)~=length(y)
    disp('Attention ! Les dimensions des vecteurs en entrée ne sont pas identiques.');
end

N=length(y);
yw=window(type_fenetre,N);

  // 're' : Rectangular window.
  // 'tr' : Triangular window.
  // 'hm' : Hamming window.
  // 'hn' : Hanning window.
  // 'kr' : Kaiser window with parameter beta (n,beta)
  // 'ch' : Chebyshev window 
  
y=y.*yw;

dt=abs(t(2)-t(1));
tmax=(N-1).*dt; // tmax =/= max(t) car min(t) peut être différent de 0 !!
                // N points donc N-1 intervalles
deltanu=1/tmax;
F=deltanu.*(0:1:N-1);

// Création du vecteur amplitude de Fourier
Xc=fft(y)./N; // coefficients de Fourier complexes (pour Func_TFI.sci)
              // le facteur 1/N : normalisation à l'amplitude
X=abs(Xc); // valeur absolue des coeffs de Fourier complexes
//X=fftshift(X); // symétrise le spectre autour de 0


    
endfunction